Arma 3 Black Fade-In Intro


Arma3 v1.50
Rip on the BIS forums had asked about a black fade in intro for his new mission. There’s countless ways of doing this but thanks to a hint from polpox I discovered that the new Bootcamp mission has introduced a function that makes a nice looking “infoText” effect. So I took some samples from the various ways I’ve done this before and came up with this.

Save the code as missionIntro.sqf. You can then call it from initPlayerLocal.sqf. There’s quite a few options you can set each with it’s own default. One “gotcha” is that if you don’t put anything in for any of the three first parameters the text typing effect will display %1, so if you want those blank put a space as in the examples.

missionIntro.sqf:

/*
	Author: kylania

	Description:
	Fade in from black intro, with a quote and Arma 3 style SitRep Date/Time/Mission credits.  
	Run via execVM from playerInitLocal.sqf

	Parameter(s):
	0: STRING - Name of the mission.  SemiBold font under date during sitrep typing effect. Default: "An Arma 3 mission"
	1: STRING - Author of the mission.  Displayed under the mission name in medium font. Use a " " for nothing. Default: "by a Community Author"
	2: STRING - Version of the mission.  Displayed under the mission author in a medium font. Use a " " for nothing. Default: "Version 1.0"
	3: STRING - Quote for center screen display on black screen.  Default: "Not so long ago, not so far away...\n\n-A quote"
	4: NUMBER - Duration of quote display.  Default: 9
	
	
	Returns:
	Nothing.
	
	Examples:
	["Jungle Trek", "By Rip", "Version 1", '"A cat is a lion in a jungle of small bushes."\n\n-Indian proverb'] execVM "missionIntro.sqf";
	["A Mission", " ", " ", "", 0] execVM "missionIntro.sqf";
*/

// Start with a silent black screen.
titleCut ["", "BLACK FADED", 999];
0 fadeSound 0;

// Spawn text effects.
_this spawn {

	
	params[
		["_missionName", "An Arma 3 mission"],
		["_missionAuthor", "by a Community Author"],
		["_missionVersion", "Version 1.0"],
		["_quote", "Not so long ago, not so far away...\n\n-A quote"],
		["_duration", 9]
	];

	// Starting quote as volume fades in.
	titleText [_quote,"PLAIN"];
	titleFadeOut _duration;
	_duration fadeSound 1;
	sleep (_duration - 2);

	// New "sitrep style" text in bottom right corner, typed out over time.
	[ 
		[_missionName,"font = 'PuristaSemiBold'"],
		["","<br/>"],
		[_missionAuthor,"font = 'PuristaMedium'"],
		["","<br/>"],
		[_missionVersion,"font = 'PuristaLight'"]
	]  execVM "\a3\missions_f_bootcamp\Campaign\Functions\GUI\fn_SITREP.sqf";

	// Fade from black, to blur, to clear as text types.
	sleep 3;
	"dynamicBlur" ppEffectEnable true;   
	"dynamicBlur" ppEffectAdjust [6];   
	"dynamicBlur" ppEffectCommit 0;     
	"dynamicBlur" ppEffectAdjust [0.0];  
	"dynamicBlur" ppEffectCommit 5;  
	titleCut ["", "BLACK IN", 5];
};
  1. No comments yet.
(will not be published)