ArmAScript Examples

//////////////////////////////////////////////////////////////////
// Function file for ArmA 2: Operation Arrowhead
// Created by: kylania (Some code from shk)
//////////////////////////////////////////////////////////////////
// This script, called from a trigger, will pick a destination and spawn guys on it.

// Don't allow a new wave if a current wave is active.
if (respawnAble) then {

	// Initialize Functions
	waitUntil{!(isNil "BIS_fnc_init")};
	waitUntil{!(isNil "BIS_MPF_InitDone")};

	// Run from a trigger it will activate on all clients, by making
	// it check for isServer this will only run on the server.  The
	// rHINT function will broadcast the direction to all clients.
	// This way we only get one direction instead of everyone getting
	// a different direction.
	if (isServer) then {
		_rndDir = ["North","East","South","West"] select floor(random 4);
		_rndDirhint = [nil,nil,"per",rHINT,_rndDir] call RE;

	// If you only wanted one of the two markers to get guys use this line.
	//_markerRnd = curDir + "spawn" + str(ceil(random 2));
	_marker1 = _rndDir + "spawn1";
	_marker2 = _rndDir + "spawn2";

	// How many enemies in each group.
	_enemyCount = _this select 0;

	// Warn of the incoming attack.
	hint format["%1 Spawn activated!", _rndDir];

	// Spawn the first group and have them attack.
	grp = [getMarkerPos _marker1, east, _enemyCount] call BIS_fnc_spawnGroup;
	null = [grp,(getMarkerPos "infdestination")] call BIS_fnc_taskAttack; 

	// Spawn the second group and have them attack.
	grp2 = [getMarkerPos _marker2, east, _enemyCount] call BIS_fnc_spawnGroup;
	null = [grp2, (getMarkerPos "infdestination")] call BIS_fnc_taskAttack;
	};

} else {
	// If there's currently an attack underway, remind the player of that instead of spawning new.
	hint "Attack underway!";
};